generate.cs

Go to the documentation of this file.

#version 310 es

/* Copyright (c) 2015-2017, ARM Limited and Contributors
 *
 * SPDX-License-Identifier: MIT
 *
 * Permission is hereby granted, free of charge,
 * to any person obtaining a copy of this software and associated documentation files (the "Software"),
 * to deal in the Software without restriction, including without limitation the rights to
 * use, copy, modify, merge, publish, distribute, sublicense, and/or sell copies of the Software,
 * and to permit persons to whom the Software is furnished to do so, subject to the following conditions:
 *
 * The above copyright notice and this permission notice shall be included in all copies or substantial portions of the Software.
 *
 * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR IMPLIED,
 * INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
 * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.
 * IN NO EVENT SHALL THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY,
 * WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM,
 * OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
 */

precision highp float;
layout (local_size_x = 4, local_size_y = 4, local_size_z = 4) in;
layout (binding = 0, r32f) writeonly highp uniform image3D outSurface;

uniform vec3 sphere_pos;
uniform float sphere_radius;
uniform int dimension;
uniform float time;

float snoise(vec3 v);

float WeirdFloor(vec3 p)
{
    float f = p.y;
    if (abs(p.y) < 0.1)
    {
        vec3 offset = vec3(0.1, 0.0, 0.07) * time;
        f += 0.4 * snoise(p * 1.7 + offset);
    }
    return f;
}

float Sphere(vec3 p, float r2)
{
    return dot(p, p) - r2;
}

float Cloud(vec3 p, vec3 center)
{
    vec3 q = p - center + vec3(0.03, 0.0, 0.02) * time;
    q.x = mod(q.x + 1.0, 2.0) - 1.0;
    q.z = mod(q.z + 1.5, 3.0) - 1.5;
    q.y *= 4.0;
    q.x *= 1.5;
    q.z *= 1.5;
    float f = Sphere(q, 0.3*0.3);
    f -= 0.2 * snoise(q * 1.2 + center * 1024.0 - vec3(0.05, 0.03, 0.02) * time);
    return f;
}

float Scene(vec3 p)
{
    float f = WeirdFloor(p);
    if (p.y > 0.5)
    {
        f = min(f, Cloud(p, vec3(0.5, 0.7, -0.3)));
        f = min(f, Cloud(p, vec3(-0.5, 0.7, 0.7)));
    }
    f = max(f, -Sphere(p - sphere_pos, sphere_radius));
    return f;
}

void main()
{
    ivec3 texel = ivec3(gl_GlobalInvocationID.xyz);
    ivec3 size = imageSize(outSurface);

    // Don't write outside texture
    // (Needed for this texture, since we invoke more
    // work units than the size of the texture).
    if (texel.x >= size.x ||
        texel.y >= size.y ||
        texel.z >= size.z)
        return;

    // Make sure that we sample the correct position in space here!
    // Let's say our (1D) cell complex has a grid size of N=4, like so:
    //      | o | o | o | o |
    //      +---+---+---+---+---> x
    //     -1  -.5  0  .5   1
    // The world space position of the centroids are -.75, -.25, .25, and .75.
    // Each cell must sample its 2 adjacent edges. I.e. the first cell
    // should sample the function at -1.0 and -0.5.
    vec3 p = vec3(-1.0) + 2.0 * vec3(texel) / float(dimension - 1);
    imageStore(outSurface, texel, vec4(Scene(p)));
}

// Description : Array and textureless GLSL 2D/3D/4D simplex
//               noise functions.
//      Author : Ian McEwan, Ashima Arts.
//  Maintainer : ijm
//     Lastmod : 20110822 (ijm)
//     License : Copyright (C) 2011 Ashima Arts. All rights reserved.
//               Distributed under the MIT License. See LICENSE file.
//               https://github.com/ashima/webgl-noise
//

vec3 mod289(vec3 x) {
    return x - floor(x * (1.0 / 289.0)) * 289.0;
}

vec4 mod289(vec4 x) {
    return x - floor(x * (1.0 / 289.0)) * 289.0;
}

vec4 permute(vec4 x) {
  return mod289(((x*34.0)+1.0)*x);
}

vec4 taylorInvSqrt(vec4 r)
{
    return 1.79284291400159 - 0.85373472095314 * r;
}

float snoise(vec3 v)
{
    const vec2  C = vec2(1.0/6.0, 1.0/3.0) ;
    const vec4  D = vec4(0.0, 0.5, 1.0, 2.0);

    // First corner
    vec3 i  = floor(v + dot(v, C.yyy) );
    vec3 x0 =   v - i + dot(i, C.xxx) ;

    // Other corners
    vec3 g = step(x0.yzx, x0.xyz);
    vec3 l = 1.0 - g;
    vec3 i1 = min( g.xyz, l.zxy );
    vec3 i2 = max( g.xyz, l.zxy );

    //   x0 = x0 - 0.0 + 0.0 * C.xxx;
    //   x1 = x0 - i1  + 1.0 * C.xxx;
    //   x2 = x0 - i2  + 2.0 * C.xxx;
    //   x3 = x0 - 1.0 + 3.0 * C.xxx;
    vec3 x1 = x0 - i1 + C.xxx;
    vec3 x2 = x0 - i2 + C.yyy; // 2.0*C.x = 1/3 = C.y
    vec3 x3 = x0 - D.yyy;      // -1.0+3.0*C.x = -0.5 = -D.y

    // Permutations
    i = mod289(i);
    vec4 p = permute( permute( permute(
               i.z + vec4(0.0, i1.z, i2.z, 1.0 ))
             + i.y + vec4(0.0, i1.y, i2.y, 1.0 ))
             + i.x + vec4(0.0, i1.x, i2.x, 1.0 ));

    // Gradients: 7x7 points over a square, mapped onto an octahedron.
    // The ring size 17*17 = 289 is close to a multiple of 49 (49*6 = 294)
    float n_ = 0.142857142857; // 1.0/7.0
    vec3  ns = n_ * D.wyz - D.xzx;

    vec4 j = p - 49.0 * floor(p * ns.z * ns.z);  //  mod(p,7*7)

    vec4 x_ = floor(j * ns.z);
    vec4 y_ = floor(j - 7.0 * x_ );    // mod(j,N)

    vec4 x = x_ *ns.x + ns.yyyy;
    vec4 y = y_ *ns.x + ns.yyyy;
    vec4 h = 1.0 - abs(x) - abs(y);

    vec4 b0 = vec4( x.xy, y.xy );
    vec4 b1 = vec4( x.zw, y.zw );

    //vec4 s0 = vec4(lessThan(b0,0.0))*2.0 - 1.0;
    //vec4 s1 = vec4(lessThan(b1,0.0))*2.0 - 1.0;
    vec4 s0 = floor(b0)*2.0 + 1.0;
    vec4 s1 = floor(b1)*2.0 + 1.0;
    vec4 sh = -step(h, vec4(0.0));

    vec4 a0 = b0.xzyw + s0.xzyw*sh.xxyy ;
    vec4 a1 = b1.xzyw + s1.xzyw*sh.zzww ;

    vec3 p0 = vec3(a0.xy,h.x);
    vec3 p1 = vec3(a0.zw,h.y);
    vec3 p2 = vec3(a1.xy,h.z);
    vec3 p3 = vec3(a1.zw,h.w);

    //Normalise gradients
    vec4 norm = taylorInvSqrt(vec4(dot(p0,p0), dot(p1,p1), dot(p2, p2), dot(p3,p3)));
    p0 *= norm.x;
    p1 *= norm.y;
    p2 *= norm.z;
    p3 *= norm.w;

    // Mix final noise value
    vec4 m = max(0.6 - vec4(dot(x0,x0), dot(x1,x1), dot(x2,x2), dot(x3,x3)), 0.0);
    m = m * m;
    return 42.0 * dot( m*m, vec4( dot(p0,x0), dot(p1,x1),
                                  dot(p2,x2), dot(p3,x3) ) );
}